上へESP8266 で IFTTT を使ってtwitterにつぶやく
[前 3.5 Maker イベントを起こすための情報を集める]

ESP8266 で IFTTT を使ってtwitterにつぶやく

3.6 ESP8266 のプログラムを用意する

ESP8266 の開発環境に Arduino IDE を使うので用意しておきます(Arduino IDE に Staging(Stable)版ESP8266 ボードをインストールする方法)。

ESP8266の接続する無線LANのSSIDなどを調べておきます。必要になるのは次の項目です。

無線LANのSSID (SSID)
無線LANのパスワード (PASS)
Maker サービスのイベント名(EventName)
Maker サービスのキー(MakerKey)
Maker サービスのアクセス用サーバの証明書のSHA-1 フィンガープリント

今回は EventName は twittest, MakerKey は fQ9sITF4nPIv-jL2ZhfOv です。フィンガープリントは C0:5D:08:5E:E1:3E:E0:66:F3:79:27:1A:CA:1F:FC:09:24:11:61:62 です。

プログラム（スケッチ）は HTTPS アクセスするので ESP8266 のライブラリをインストールしたときに含まれる HTTPSRequest (ESP8266Wifi内) を基にし、以下のようになりました。プログラム内の PASS, EventName, MakerKey を自分で用意したものに書き換えてください。フィンガープリントは : (コロン) ではなく空白文字（半角）で区切ります。イベントのURIには HTTP POST でアクセスしていて、3つの値, 12345, abcdef, xyz を JSON 形式で渡しています。

ESP8266 の電源が入るかリセットがかかると、1回だけ Maker イベントが起き Twitterに次のように投稿されます。

#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>

const char* ssid = "SSID";
const char* password = "PASS";

const char* host = "maker.ifttt.com";
const int httpsPort = 443;

const char* iftttEvent = "EventName";
const char* iftttKey = "MakerKey";

// Use web browser to view and copy
// SHA1 fingerprint of the certificate
const char* fingerprint = "C0 5D 08 5E E1 3E E0 66 F3 79 27 1A CA 1F FC 09 24 11 61 62";

void setup() {
  Serial.begin(115200);
  Serial.println();
  Serial.print("connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  // Use WiFiClientSecure class to create TLS connection
  WiFiClientSecure client;
  Serial.print("connecting to ");
  Serial.println(host);
  if (!client.connect(host, httpsPort)) {
    Serial.println("connection failed");
    return;
  }

  if (client.verify(fingerprint, host)) {
    Serial.println("certificate matches");
  } else {
    Serial.println("certificate doesn't match");
  }

  String url = "/trigger/";
  url = url + iftttEvent + "/with/key/" + iftttKey;
  Serial.print("requesting URL: ");
  Serial.println(url);

  String data = String("{ \"value1\" : \"") + 12345 + "\", " 
                + "\"value2\" : \"" + "abcdef" + "\", "
                + "\"value3\" : \"" + "xyz" + "\" } ";

                Serial.println(data);

  client.print(String("POST ") + url + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "User-Agent: BuildFailureDetectorESP8266\r\n" +
               "Connection: close\r\n" +
               "Content-Type: application/json; charset=utf-8\r\n" +
               "Content-Length: " + data.length() + "\r\n\r\n" +
                data + 
               "\r\n"
               );

  Serial.println("request sent");
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") {
      Serial.println("headers received");
      break;
    }
  }
  String line = client.readStringUntil('\n');

  Serial.println("reply was:");
  Serial.println("==========");
  Serial.println(line);
  Serial.println("==========");
  Serial.println("closing connection");
}

void loop() {
}

[前 3.5 Maker イベントを起こすための情報を集める]
上へESP8266 で IFTTT を使ってtwitterにつぶやく